Docker reference deployment

// internal tables
// with `time` and `sym` columns added by RT client for compatibility
(`$"_prtnEnd")set ([] time:"n"$(); sym:`$(); signal:`$(); endTS:"p"$(); opts:());
(`$"_reload")set ([] time:"n"$(); sym:`$(); mount:`$(); params:(); asm:`$())
(`$"_heartbeats")set ([] time:"n"$(); sym:`$(); foo:"j"$())
(`$"_batchIngest")set ([] time:"n"$(); sym: `$(); batchUpdType: `$(); session:`$(); address:`$(); callback:(); merge:"b"$(); datacheck:"b"$());
(`$"_batchDelete")set ([] time:"n"$(); sym: `$(); batchUpdType: `$(); session:`$(); address:`$(); callback:(); endTS:"p"$(); filter:(); startTS:"p"$(); table:`$());
(`$"_schemaChange")set ([] time:"n"$(); sym: `$(); batchUpdType: `$(); session:`$(); address:`$(); callback:(); changes:());
trade:([] time:"n"$(); sym:`$(); realTime:"p"$(); price:"f"$(); size:"j"$())
quote:([] time:"n"$(); sym:`$(); realTime:"p"$();
 bid:"f"$(); ask:"f"$(); bidSize:"j"$(); askSize:"j"$())

// Sample DA custom file.
// Can load other files within this file. Note that the current directory
// is the directory of this file (in this example: /opt/kx/custom).
/ \l subFolder/otherFile1.q
/ \l subFolder/otherFile2.q
//
// @desc Define a new API. Counts number of entries by specified columns.
//
// @param table     {symbol}            Table name.
// @param byCols    {symbol|symbol[]}   Column(s) to count by.
// @param startTS   {timestamp}         Start time (inclusive).
// @param endTS     {timestamp}         End time (exclusive).
//
// @return          {table}             Count by specified columns.
//
countBy:{[table;startTS;endTS;byCols]
 ?[table;enlist(within;`realTime;(startTS;endTS-1));{x!x,:()}byCols;enlist[`cnt]!enlist(count;`i)]
 }
// Register with the DA process.
.da.registerAPI[`countBy;
 .kxi.metaDescription["Define a new API. Counts number of entries by specified columns."],
 .kxi.metaParam[`name`type`isReq`description!(`table;-11h;1b;"Table name.")],
 .kxi.metaParam[`name`type`isReq`description!(`byCols;-11 11h;1b;"Column(s) to count by.")],
 .kxi.metaParam[`name`type`isReq`description!(`startTS;-12h;1b;"Start time (inclusive).")],
 .kxi.metaParam[`name`type`isReq`description!(`endTS;-12h;1b;"End time (exclusive).")],
 .kxi.metaReturn[`type`description!(98h;"Count by specified columns.")],
 .kxi.metaMisc[enlist[`safe]!enlist 1b]
 ]

// Sample Agg custom file.
// Can load other files within this file. Note that the current directory
// is the directory of this file (in this example: /opt/kx/custom).
/ \l subFolder/otherFile1.q
/ \l subFolder/otherFile2.q
//
// @desc An override to the default ping aggregation function. Instead of doing a raze,
// we just take the min (so true indicates all targets successful).
//
// @param res   {boolean[]} Results from the DAPs.
//
// @return      {boolean}   Min of all DAP results.
//
pingAggOverride:{[res]
 .kxi.response.ok min res
 }
//
// @desc Agg function that does a plus join on a list of tables.
//
// @param tbls  {table[]}   List plus-joinable tables.
//
// @return      {table}     Plus join.
//
pjAgg:{[tbls]
 .kxi.response.ok (pj/)tbls
 }
//
// @desc Agg function that does an average daily count by sym.
//
// @param tbls  {table[]}   List of tables with `` `sym`date`cnt`` columns.
//
// @return      {table}     Average count by sym
//
avAgg:{[tbls]
 res:select sum cnt by sym,date from raze 0!'tbls; / Join common dates
 .kxi.response.ok select avg cnt by sym from res / Average
 }
//
// @desc Defers on receipt of trade data so we can get quote data. Assuming trade data has been received in previous `.kxi.getData` request.
//
// @param trade {table} Trade data.
//
// @return {table}  Results from joined trade and quote data
basicDefer:{[trade]
 .kxi.context.set[`trade;trade];
 args:`table`labels`startTS`endTS`agg`sortCols!
 (`quote;enl[`region]!enl`canada;"p"$"d"$min trade`realTime;1+max trade`realTime;
 `sym`realTime`ask`askSize`bid`bidSize;`sym`realTime); / Args to getData for quotes
 .kxi.response.callAPI[`.kxi.getData;args;`.custom.basicDeferCB;()!()]
 }
basicDeferCB:{[quote]
 trade:.kxi.context.get`trade; / Recover trade data
 res:aj[`sym`realTime;trade;quote]; / Join
 round:{("j"$100*x)%100}; / Round to two decimals
 .kxi.response.ok update round price,round bid,round ask from res
 }
//
// In order to be usable, aggregation functions MUST be registered with the Agg process. When registering,
// one can also set the aggregation function as the default aggregation function for one or more APIs.
// For example, Suppose we had an API defined in the DAPs that peforms a "count by" operation on a table:
//
// countBy:{[table;startTS;endTS;byCols]
//     ?[table;enlist(within;`realTime;(startTS;endTS-1));{x!x,:()}byCols;enlist[`cnt]!enlist(count;`i)]
//     }
//
// We can then register our aggregations functions thusly:
//
.sgagg.registerAggFn[`pingAggOverride;
 .kxi.metaDescription["Custom override to .kxi.ping"],
 .kxi.metaParam[`name`type`description!(`res;1h;"List of booleans indicating ping was successful")],
 .kxi.metaReturn[`type`description!(-1h;"The worst of all results")];
 `$()
 ]
.sgagg.registerAggFn[`pjAgg;
 .kxi.metaDescription["Plus join aggregation"],
 .kxi.metaParam[`name`type`description!(`tbls;0h;"Tables received from DAPs")],
 .kxi.metaReturn`type`description!(98h;"The plus join (over) of the tables");
 `countBy]; // Register as default aggregation function for this API
.sgagg.registerAggFn[`avAgg;
 .kxi.metaDescription["Average join aggregation"],
 .kxi.metaParam[`name`type`description!(`tbls;0h;"Tables received from DAPs")],
 .kxi.metaReturn`type`description!(98h;"The average join (over) of the tables");
 `$()
 ]
.sgagg.registerAggFn[`.custom.basicDefer;
 .kxi.metaDescription["Defers on receipt of trade data to get quote data"],
 .kxi.metaParam[`name`type`descriptions!(`trade;0h;"Trade data from DAPs")],
 .kxi.metaReturn`type`description!(98h;"Trade data asof joined with quote data");
 `$()]
//
// Note also that an aggregation function can be default aggregation function for multiple APIs. E.g.
//  .sgagg.registerAggFn[`myAggFn;();`api1`api2`api3]
//